home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Linux Cubed Series 7: Sunsite
/
Linux Cubed Series 7 - Sunsite Vol 1.iso
/
system
/
shells
/
zsh-3.0-p
/
zsh-3
/
zsh-3.0-pre3
/
configure.in
< prev
next >
Wrap
Text File
|
1996-07-10
|
19KB
|
594 lines
dnl
dnl $Id: configure.in,v 2.16 1996/07/10 20:52:55 hzoli Exp $
dnl
dnl Configure template for zsh.
dnl Process this file with autoconf to produce a configure script.
dnl
dnl Copyright (c) 1996 Richard Coleman
dnl All rights reserved.
dnl
dnl Permission is hereby granted, without written agreement and without
dnl license or royalty fees, to use, copy, modify, and distribute this
dnl software and its documentation for any purpose, provided that the
dnl above copyright notice and the following two paragraphs appear in
dnl all copies of this software.
dnl
dnl In no event shall Richard Coleman or the Zsh Development Group be liable
dnl to any party for direct, indirect, special, incidental, or consequential
dnl damages arising out of the use of this software and its documentation,
dnl even if Richard Coleman and the Zsh Development Group have been advised of
dnl the possibility of such damage.
dnl
dnl Richard Coleman and the Zsh Development Group specifically disclaim any
dnl warranties, including, but not limited to, the implied warranties of
dnl merchantability and fitness for a particular purpose. The software
dnl provided hereunder is on an "as is" basis, and Richard Coleman and the
dnl Zsh Development Group have no obligation to provide maintenance,
dnl support, updates, enhancements, or modifications.
AC_INIT(Src/zsh.h)
AC_CONFIG_HEADER(config.h)
dnl What version of zsh are we building ?
VERSION=`sed -e 's/^.*"\(.*\)"$/\1/' ${srcdir}/Src/version.h`
echo "configuring for zsh $VERSION"
AC_SUBST(VERSION)dnl
dnl ----------------------------------------------
dnl CHECK FOR MACHINE/VENDOR/OPERATING SYSTEM TYPE
dnl ----------------------------------------------
dnl Find out machine type, vendor, and operating system
dnl What type of host is this?
AC_CANONICAL_HOST
AC_DEFINE_UNQUOTED(OSTYPE, "$host_os")
AC_DEFINE_UNQUOTED(MACHTYPE, "$host_cpu")
AC_DEFINE_UNQUOTED(VENDOR, "$host_vendor")
dnl -----------------------------
dnl CHECKING COMMAND LINE OPTIONS
dnl -----------------------------
dnl Do you want to debug zsh?
undefine([zsh-debug])dnl
AC_ARG_ENABLE(zsh-debug,
[ --enable-zsh-debug use it if you want to debug zsh])
dnl Do you want zsh memory allocation routines.
undefine([zsh-mem])dnl
AC_ARG_ENABLE(zsh-mem,
[ --enable-zsh-mem use zsh memory allocation routines],
[if test x$enableval = xyes; then
AC_DEFINE(ZSH_MEM)
fi])
dnl Do you want to debug zsh memory allocation routines.
undefine([zsh-mem-debug])dnl
AC_ARG_ENABLE(zsh-mem-debug,
[ --enable-zsh-mem-debug debug zsh memory allocation routines],
[if test x$enableval = xyes; then
AC_DEFINE(ZSH_MEM_DEBUG)
fi])
dnl Do you want to print warnings when errors in memory allocation.
undefine([zsh-mem-warning])dnl
AC_ARG_ENABLE(zsh-mem-warning,
[ --enable-zsh-mem-warning print warnings when error in memory allocation],
[if test x$enableval = xyes; then
AC_DEFINE(ZSH_MEM_WARNING)
fi])
dnl Do you want to turn on error checking for free().
undefine([zsh-secure-free])dnl
AC_ARG_ENABLE(zsh-secure-free,
[ --enable-zsh-secure-free turn on error checking for free()],
[if test x$enableval = xyes; then
AC_DEFINE(ZSH_SECURE_FREE)
fi])
dnl Do you want debugging information on internal hash tables.
dnl This turns on the `hashinfo' builtin command.
undefine([zsh-hash-debug])dnl
AC_ARG_ENABLE(zsh-hash-debug,
[ --enable-zsh-hash-debug turn on debugging of internal hash tables],
[if test x$enableval = xyes; then
AC_DEFINE(ZSH_HASH_DEBUG)
fi])
dnl Pathnames for global zsh scripts
undefine([zshenv])dnl
AC_ARG_ENABLE(etcdir,
[ --enable-etcdir=directory default directory for global zsh scripts],
[etcdir="$enableval"], [etcdir=/etc])
undefine([zshenv])dnl
AC_ARG_ENABLE(zshenv,
[ --enable-zshenv=pathname the full pathname of the global zshenv script],
[zshenv="$enableval"],
[if test "x$etcdir" = xno; then
zshenv=no
else
zshenv="$etcdir/zshenv"
fi])
if test "x$zshenv" != xno; then
AC_DEFINE_UNQUOTED(GLOBAL_ZSHENV, "$zshenv")
fi
undefine([zshrc])dnl
AC_ARG_ENABLE(zshrc,
[ --enable-zshrc=pathname the full pathname of the global zshrc script],
[zshrc="$enableval"],
[if test "x$etcdir" = xno; then
zshrc=no
else
zshrc="$etcdir/zshrc"
fi])
if test "x$zshrc" != xno; then
AC_DEFINE_UNQUOTED(GLOBAL_ZSHRC, "$zshrc")
fi
undefine([zprofile])dnl
AC_ARG_ENABLE(zprofile,
[ --enable-zprofile=pathname the full pathname of the global zprofile script],
[zprofile="$enableval"],
[if test "x$etcdir" = xno; then
zprofile=no
else
zprofile="$etcdir/zprofile"
fi])
if test "x$zprofile" != xno; then
AC_DEFINE_UNQUOTED(GLOBAL_ZPROFILE, "$zprofile")
fi
undefine([zlogin])dnl
AC_ARG_ENABLE(zlogin,
[ --enable-zlogin=pathname the full pathname of the global zlogin script],
[zlogin="$enableval"],
[if test "x$etcdir" = xno; then
zlogin=no
else
zlogin="$etcdir/zlogin"
fi])
if test "x$zlogin" != xno; then
AC_DEFINE_UNQUOTED(GLOBAL_ZLOGIN, "$zlogin")
fi
undefine([zlogout])dnl
AC_ARG_ENABLE(zlogout,
[ --enable-zlogout=pathname the full pathname of the global zlogout script],
[zlogout="$enableval"],
[if test "x$etcdir" = xno; then
zlogout=no
else
zlogout="$etcdir/zlogout"
fi])
if test "x$zlogout" != xno; then
AC_DEFINE_UNQUOTED(GLOBAL_ZLOGOUT, "$zlogout")
fi
AC_SUBST(zshenv)dnl
AC_SUBST(zshrc)dnl
AC_SUBST(zprofile)dnl
AC_SUBST(zlogin)dnl
AC_SUBST(zlogout)dnl
dnl ------------------
dnl CHECK THE COMPILER
dnl ------------------
dnl We want these before the checks, so the checks can modify their values.
test -z "$CFLAGS" && CFLAGS= auto_cflags=1
if test "${enable_zsh_debug}" = yes; then
test -z "$LDFLAGS" && LDFLAGS=-g
fi
AC_PROG_CC
dnl if the user hasn't specified CFLAGS, then
dnl if compiler is gcc, then use -O2 and some warning flags
dnl else use -O
if test -n "$auto_cflags"; then
if test "${enable_zsh_debug}" = yes; then
if test -n "$GCC"; then
CFLAGS="$CFLAGS -Wall -Wno-implicit -Wmissing-prototypes -DDEBUG -g"
else
CFLAGS="$CFLAGS -DDEBUG -g"
fi
else
if test -n "$GCC"; then
CFLAGS="$CFLAGS -Wall -Wno-implicit -Wmissing-prototypes -O2 -DDEBUG"
else
CFLAGS="$CFLAGS -O -DDEBUG"
fi
fi
fi
dnl ----------
dnl SCO KLUDGE
dnl ----------
dnl Sco doesn't define any useful compiler symbol,
dnl so we will check for sco and define __sco if
dnl found.
if test `echo $host_os | sed 's/^\(...\).*/\1/'` = sco; then
CFLAGS="-D__sco $CFLAGS"
fi
AC_SUBST(CFLAGS)dnl
AC_SUBST(LDFLAGS)dnl
AC_PROG_CPP dnl Figure out how to run C preprocessor.
AC_PROG_GCC_TRADITIONAL dnl Do we need -traditional flag for gcc.
AC_C_CONST dnl Does compiler support `const'.
AC_C_CROSS dnl Are we cross compiling.
fp_C_PROTOTYPES dnl Does compiler support ANSI prototypes.
AC_CHECK_SIZEOF(long) dnl number of bytes in a long.
dnl Checking if compiler correctly cast signed to unsigned.
AC_CACHE_CHECK(if signed to unsigned casting is broken,
zsh_broken_signed_to_unsigned_casting,
[AC_TRY_RUN([main(){return((int)(unsigned char)((char) -1) == 255);}],
zsh_broken_signed_to_unsigned_casting=yes,
zsh_broken_signed_to_unsigned_casting=no)])
if test $zsh_broken_signed_to_unsigned_casting = yes; then
AC_DEFINE(BROKEN_SIGNED_TO_UNSIGNED_CASTING)
fi
dnl ------------------
dnl CHECK FOR PROGRAMS
dnl ------------------
AC_PROG_MAKE_SET dnl Does make define $MAKE
AC_PROG_INSTALL dnl Check for BSD compatible `install'
AC_PROG_AWK dnl Check for mawk,gawk,nawk, then awk.
dnl ------------------
dnl CHECK HEADER FILES
dnl ------------------
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_TIME
AC_HEADER_STAT
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(sys/time.h sys/times.h sys/select.h termcap.h termio.h \
termios.h sys/param.h sys/filio.h string.h memory.h \
limits.h fcntl.h libc.h sys/utsname.h sys/resource.h \
locale.h errno.h stdlib.h unistd.h)
dnl Some SCO systems cannot include both sys/time.h and sys/select.h
if test $ac_cv_header_sys_time_h = yes -a $ac_cv_header_sys_select_h = yes; then
AC_CACHE_CHECK(for conflicts in sys/time.h and sys/select.h,
zsh_cv_time_h_select_h_conflicts,
[AC_TRY_COMPILE([#include <sys/time.h>
#include <sys/select.h>], [int i;],
zsh_cv_time_h_select_h_conflicts=no,
zsh_cv_time_h_select_h_conflicts=yes)])
if test $zsh_cv_time_h_select_h_conflicts = yes; then
AC_DEFINE(TIME_H_SELECT_H_CONFLICTS)
fi
fi
AC_CACHE_CHECK(ut_host in struct utmp, zsh_cv_func_ut_host_in_utmp,
[AC_TRY_COMPILE(
[#include <sys/types.h>
#include <utmp.h>], [struct utmp ut; ut.ut_host;],
zsh_cv_func_ut_host_in_utmp=yes, zsh_cv_func_ut_host_in_utmp=no)])
if test $zsh_cv_func_ut_host_in_utmp = yes; then
have_ut_host=1
AC_DEFINE(HAVE_UT_HOST)
fi
if test -z "$have_ut_host"; then
AC_CACHE_CHECK(ut_host in struct utmpx, zsh_cv_func_ut_host_in_utmpx,
[AC_TRY_COMPILE([#include <sys/types.h>
#include <utmpx.h>], [struct utmpx ut; ut.ut_host;],
zsh_cv_func_ut_host_in_utmpx=yes, zsh_cv_func_ut_host_in_utmpx=no)])
if test $zsh_cv_func_ut_host_in_utmpx = yes; then
AC_DEFINE(HAVE_UTMPX_H)
AC_DEFINE(HAVE_UT_HOST)
fi
fi
AC_CACHE_CHECK(POSIX termios, zsh_cv_sys_posix_termios,
[AC_TRY_LINK([#include <sys/types.h>
#include <unistd.h>
#include <termios.h>],
[/* SunOS 4.0.3 has termios.h but not the library calls. */
tcgetattr(0, 0);],
zsh_cv_sys_posix_termios=yes, zsh_cv_sys_posix_termios=no)])
if test $zsh_cv_sys_posix_termios = yes; then
AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
zsh_cv_sys_tiocgwinsz_in_termios_h,
[AC_TRY_LINK([#include <sys/types.h>
#include <termios.h>],
[int x = TIOCGWINSZ;],
zsh_cv_sys_tiocgwinsz_in_termios_h=yes,
zsh_cv_sys_tiocgwinsz_in_termios_h=no)])
else
zsh_cv_sys_tiocgwinsz_in_termios_h=no
fi
if test $zsh_cv_sys_tiocgwinsz_in_termios_h = no; then
AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
zsh_cv_sys_tiocgwinsz_in_sys_ioctl_h,
[AC_TRY_LINK([#include <sys/types.h>
#include <sys/ioctl.h>],
[int x = TIOCGWINSZ;],
zsh_cv_sys_tiocgwinsz_in_sys_ioctl_h=yes,
zsh_cv_sys_tiocgwinsz_in_sys_ioctl_h=no)])
if test $zsh_cv_sys_tiocgwinsz_in_sys_ioctl_h = yes; then
AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
fi
fi
AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM))
dnl -------------------
dnl CHECK FOR LIBRARIES
dnl -------------------
dnl Prefer BSD termcap library to SysV curses library, except on certain
dnl versions of AIX.
if test `echo $host_os | sed 's/^.*\(aix3\.2\).*$/\1/'` = aix3.2; then
termcap_curses_order="curses ncurses termcap"
else
termcap_curses_order="termcap curses ncurses"
fi
for lib in $termcap_curses_order; do
AC_CHECK_LIB(${lib}, tgetent, [LIBS="$LIBS -l$lib"; break])
done
dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
dnl to find getdomainname and yp_all
AC_CHECK_FUNCS(getdomainname)
if test $ac_cv_func_getdomainname = no; then
AC_CHECK_LIB(nsl, getdomainname)
fi
dnl ---------------------
dnl CHECK TERMCAP LIBRARY
dnl ---------------------
dnl Checks for external variable ospeed in the termcap library.
AC_CACHE_CHECK(if an include file defines ospeed,
zsh_cv_include_defines_ospeed,
[AC_TRY_LINK(
[#include <sys/types.h>
#if HAVE_TERMIOS_H
#include <termios.h>
#endif
#if HAVE_TERMCAP_H
#include <termcap.h>
#endif], [ospeed = 0;],
zsh_cv_include_defines_ospeed=yes,
zsh_cv_include_defines_ospeed=no)])
if test $zsh_cv_include_defines_ospeed = no; then
AC_CACHE_CHECK(if you must define ospeed,
zsh_cv_must_define_ospeed,
[AC_TRY_LINK( ,[extern short ospeed; ospeed = 0;],
zsh_cv_must_define_ospeed=yes,
zsh_cv_must_define_ospeed=no)])
fi
if test $zsh_cv_include_defines_ospeed = yes; then
AC_DEFINE(HAVE_OSPEED)
elif test $zsh_cv_must_define_ospeed = yes; then
AC_DEFINE(HAVE_OSPEED)
AC_DEFINE(MUST_DEFINE_OSPEED)
fi
dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
AC_CACHE_CHECK(if tgetent accepts NULL,
zsh_cv_tgetent_accepts_null,
[AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
zsh_cv_tgetent_accepts_null=yes,
zsh_cv_tgetent_accepts_null=no)])
if test $zsh_cv_tgetent_accepts_null = yes; then
AC_DEFINE(TGETENT_ACCEPTS_NULL)
fi
dnl --------------
dnl CHECK TYPEDEFS
dnl --------------
AC_TYPE_SIGNAL
AC_TYPE_PID_T
AC_TYPE_OFF_T
AC_TYPE_MODE_T
AC_TYPE_UID_T
AC_TYPE_SIZE_T
dnl Check for sigset_t. Currently I'm looking in
dnl <sys/types.h> and <signal.h>. Others might need
dnl to be added.
AC_CACHE_CHECK(for sigset_t, zsh_cv_sigset_t,
[AC_TRY_COMPILE(
[#include <sys/types.h>
#include <signal.h>], [sigset_t tempsigset;],
zsh_cv_sigset_t=yes, zsh_cv_sigset_t=no)])
if test $zsh_cv_sigset_t = no; then
AC_DEFINE(sigset_t, unsigned int)
fi
dnl Check for struct timezone since some old SCO versions do not define it
AC_CACHE_CHECK(for struct timezone, zsh_cv_struct_timezone,
[AC_TRY_COMPILE(
[#include <sys/time.h>], [struct timezone dummy_tz;],
zsh_cv_struct_timezone=yes, zsh_cv_struct_timezone=no)])
if test $zsh_cv_struct_timezone = yes; then
AC_DEFINE(HAVE_STRUCT_TIMEZONE)
fi
dnl ---------------
dnl CHECK FUNCTIONS
dnl ---------------
AC_FUNC_GETPGRP
dnl need to integrate this function
dnl AC_FUNC_STRFTIME
AC_CHECK_FUNCS(strftime waitpid select tcsetpgrp tcgetattr strstr lstat \
getlogin setpgid gettimeofday gethostname mkfifo wait3 difftime \
sigblock sigsetmask sigrelse sighold killpg sigaction getrlimit \
sigprocmask setuid seteuid setreuid setresuid strerror strcoll)
dnl -------------
dnl CHECK SIGNALS
dnl -------------
dnl What style of signal do you have (POSIX, BSD, or SYSV)?
AC_MSG_CHECKING(what style of signals to use)
if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
signals_style=POSIX_SIGNALS
AC_DEFINE(POSIX_SIGNALS)
elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
signals_style=BSD_SIGNALS
AC_DEFINE(BSD_SIGNALS)
elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
signals_style=SYSV_SIGNALS
AC_DEFINE(SYSV_SIGNALS)
else
signals_style=NO_SIGNAL_BLOCKING
AC_DEFINE(NO_SIGNAL_BLOCKING)
fi
AC_DEFINE_UNQUOTED($signals_style)
AC_MSG_RESULT($signals_style)
dnl Where is <signal.h> located? Needed as input for signals.awk
AC_MSG_CHECKING(where signal.h is located)
for SIGNAL_H in /usr/include/bsd/sys/signal.h dnl Next
/usr/include/asm/signal.h dnl Linux 1.3.0 and above
/usr/include/linux/signal.h dnl Linux up to 1.2.11
/usr/include/sys/signal.h dnl Almost everybody else
/dev/null; dnl Just in case we fall through
do
test -f $SIGNAL_H && \
grep '#[ ]*define[ ][ ]*SIG[0-9A-Z]*[ ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
break
done
AC_MSG_RESULT($SIGNAL_H)
AC_SUBST(SIGNAL_H)dnl
dnl ----------------------------
dnl CHECK FOR /dev/fd FILESYSTEM
dnl ----------------------------
AC_CACHE_CHECK(for /dev/fd filesystem, zsh_cv_have_dev_fd,
[test -d /dev/fd && zsh_cv_have_dev_fd=yes || zsh_cv_have_dev_fd=no])
if test $zsh_cv_have_dev_fd = yes; then
AC_DEFINE(HAVE_DEV_FD)
fi
dnl ---------------------------------
dnl CHECK FOR RFS SUPERROOT DIRECTORY
dnl ---------------------------------
AC_CACHE_CHECK(for RFS superroot directory, zsh_cv_have_superroot,
[test -d /../.LOCALROOT && zsh_cv_have_superroot=yes || zsh_cv_have_superroot=no])
if test $zsh_cv_have_superroot = yes; then
AC_DEFINE(HAVE_SUPERROOT)
fi
dnl -------------
dnl CHECK FOR NIS
dnl -------------
AC_CACHE_CHECK(for NIS, zsh_cv_have_nis,
[test -f /usr/bin/ypcat && /usr/bin/ypcat passwd.byname > /dev/null 2>&1 && \
zsh_cv_have_nis=yes || zsh_cv_have_nis=no])
if test $zsh_cv_have_nis = yes; then
AC_DEFINE(HAVE_NIS)
fi
dnl -----------------
dnl CHECK FOR NISPLUS
dnl -----------------
AC_CACHE_CHECK(for NIS+, zsh_cv_have_nis_plus,
[test -f /usr/bin/nisls && /usr/bin/nisls > /dev/null 2>&1 && \
zsh_cv_have_nis_plus=yes || zsh_cv_have_nis_plus=no])
if test $zsh_cv_have_nis_plus = yes; then
AC_DEFINE(HAVE_NIS_PLUS)
fi
dnl -------------------------------
dnl CHECK FOR LOCATION OF UTMP FILE
dnl -------------------------------
AC_MSG_CHECKING(where utmp is located)
for utmp_file in /etc/utmp dnl
/usr/etc/utmp dnl
/var/adm/utmp dnl
/usr/adm/utmp dnl
/var/run/utmp dnl
/dev/null; dnl Just in case we fall through
do
test -f $utmp_file && break
done
AC_MSG_RESULT($utmp_file)
AC_DEFINE_UNQUOTED(UTMP_FILE_CONFIG, "$utmp_file")
dnl -------------------------------
dnl CHECK FOR LOCATION OF WTMP FILE
dnl -------------------------------
AC_MSG_CHECKING(where wtmp is located)
for wtmp_file in /etc/wtmp dnl
/usr/etc/wtmp dnl
/var/adm/wtmp dnl
/usr/adm/wtmp dnl
/var/log/wtmp dnl
/dev/null; dnl Just in case we fall through
do
test -f $wtmp_file && break
done
AC_DEFINE_UNQUOTED(WTMP_FILE_CONFIG, "$wtmp_file")
AC_MSG_RESULT($wtmp_file)
dnl ----------------------------
dnl TYPEAHEAD KLUDGE FOR ULTRIX
dnl ----------------------------
dnl Some systems clobber typeahead when you go from canonical input
dnl processing to non-canonical, so we need a FIONREAD ioctl.
dnl I don't know how to check this with configure, so I am using the
dnl system names directly.
dnl The doubled square brackets are necessary because autoconf uses m4.
AC_CACHE_CHECK(if typeahead needs FIONREAD, zsh_cv_clobbers_typeahead,
[test `echo $host_os | sed 's/^\([[a-z]]*\).*/\1/'` = ultrix &&
zsh_cv_clobbers_typeahead=yes || zsh_cv_clobbers_typeahead=no])
if test $zsh_cv_clobbers_typeahead = yes; then
AC_DEFINE(CLOBBERS_TYPEAHEAD)
fi
dnl -------------------
dnl brk/sbrk PROTOTYPES
dnl -------------------
AC_CACHE_CHECK(for brk() prototype in <unistd.h>,
zsh_cv_brk_proto_in_unistd_h,
[AC_TRY_COMPILE([#include <unistd.h>
double brk();], [int i;],
zsh_cv_brk_proto_in_unistd_h=no, zsh_cv_brk_proto_in_unistd_h=yes)])
if test $zsh_cv_brk_proto_in_unistd_h = yes; then
AC_DEFINE(HAVE_BRK_PROTO)
fi
AC_CACHE_CHECK(for sbrk() prototype in <unistd.h>,
zsh_cv_sbrk_proto_in_unistd_h,
[AC_TRY_COMPILE([#include <unistd.h>
double sbrk();], [int i;],
zsh_cv_sbrk_proto_in_unistd_h=no, zsh_cv_sbrk_proto_in_unistd_h=yes)])
if test $zsh_cv_sbrk_proto_in_unistd_h = yes; then
AC_DEFINE(HAVE_SBRK_PROTO)
fi
AC_OUTPUT(Makefile Src/Makefile Doc/Makefile Etc/Makefile Misc/Makefile \
Util/Makefile Functions/Makefile StartupFiles/Makefile, \
[test -z "$CONFIG_HEADERS" || echo > stamp-h])
eval "zshbin1=${bindir}"
eval "zshbin2=${zshbin1}"
eval "zshman=${mandir}"
eval "zshinfo=${infodir}"
echo "
zsh configuration
-----------------
zsh version : ${VERSION}
host operating system : ${host_os}
source code location : ${srcdir}
compiler : ${CC}
compiler flags : ${CFLAGS}
binary install path : ${zshbin2}
man page install path : ${zshman}
info install path : ${zshinfo}"
echo ""